add_library(fiko_istakip STATIC
  src/model.cpp
  src/depo.cpp
  src/merkez.cpp
  src/istemci.cpp
  src/kanal.cpp
)
add_library(fiko::istakip ALIAS fiko_istakip)

target_include_directories(fiko_istakip PUBLIC include)
target_link_libraries(fiko_istakip PUBLIC fiko::orkestra)

# MongoDB sürücüsü (mongocxx, Apache 2.0) — bulunamazsa DepoMongo derlenmez,
# motor Mongo'suz da yeşil kalır (DepoBellek + testler etkilenmez).
find_package(mongocxx CONFIG QUIET)
if(TARGET mongo::mongocxx_shared OR TARGET mongo::mongocxx_static)
  target_sources(fiko_istakip PRIVATE src/depo_mongo.cpp)
  target_compile_definitions(fiko_istakip PUBLIC FIKO_ISTAKIP_MONGO=1)
  target_link_libraries(fiko_istakip PRIVATE
    $<IF:$<TARGET_EXISTS:mongo::mongocxx_static>,mongo::mongocxx_static,mongo::mongocxx_shared>)
else()
  target_compile_definitions(fiko_istakip PUBLIC FIKO_ISTAKIP_MONGO=0)
endif()

add_executable(fiko_istakip_test
  test/test_main.cpp
  test/test_model.cpp
  test/test_merkez.cpp
  test/test_istemci.cpp
  test/test_kanal.cpp
  test/test_depo_mongo.cpp
)
target_link_libraries(fiko_istakip_test PRIVATE fiko_istakip)
target_include_directories(fiko_istakip_test PRIVATE ${CMAKE_SOURCE_DIR}/motor/core/test)
add_test(NAME istakip COMMAND fiko_istakip_test)