@echo off
chcp 65001 >nul
setlocal
cd /d "%~dp0"

echo ============================================
echo   FikoYT Federation - Baslatma Scripti
echo   (Live Reload aktif)
echo ============================================
echo.

if not exist "node_modules" (
    echo [1/4] node_modules bulunamadi, bagimliliklar kuruluyor...
    call npm install --legacy-peer-deps --no-audit --no-fund
    if errorlevel 1 (
        echo HATA: npm install basarisiz oldu.
        pause
        exit /b 1
    )
) else (
    echo [1/4] node_modules mevcut, kurulum atlaniyor.
)

echo.
echo Shared kutuphanesi derleniyor...
call npx ng build shared --configuration development
if errorlevel 1 (
    echo HATA: shared build basarisiz oldu.
    pause
    exit /b 1
) else (
    echo Shared kutuphanesi basariyla derlendi.
)

echo.
echo [3/4] Uygulama remote'lari baslatiliyor...
echo        Live Reload: AKTIF
start "ana-uygulama (4201)" cmd /k "cd /d "%~dp0" && npx ng serve ana-uygulama --port 4201"
start "hmi-pano (4202)" cmd /k "cd /d "%~dp0" && npx ng serve hmi-pano --port 4202"
start "paylasim (4203)" cmd /k "cd /d "%~dp0" && npx ng serve paylasim --port 4203"
start "uc-boyut (4204)" cmd /k "cd /d "%~dp0" && npx ng serve uc-boyut --port 4204"

echo Remote'larin derlenmesi icin bekleniyor...
timeout /t 8 /nobreak >nul

echo.
echo [4/4] Kabuk ^(host, port 4200^) baslatiliyor...
echo        Live Reload: AKTIF
start "kabuk (4200)" cmd /k "cd /d "%~dp0" && npx ng serve kabuk --port 4200"

echo Host'un derlenmesi icin bekleniyor...
timeout /t 8 /nobreak >nul

echo.
echo Tarayici aciliyor: https://fikoyt.com:4200
echo   Agdaki diger cihazlardan: https://fikoyt.com:4200 (IP ile erisim icin cert SAN gerekir - simdilik domain ile girin)  (ipconfig ile ogrenin)
start "" "https://fikoyt.com:4200"

echo.
echo ============================================
echo   Her iki sunucu da ayri pencerelerde calisiyor.
echo   Dosya degisikliklerinde OTOMATIK yeniden derlenir.
echo   Durdurmak icin o pencereleri kapatmaniz yeterli.
echo   Bu pencereyi kapatabilirsiniz.
echo ============================================