@echo off
chcp 65001 >nul
title AI Influencer Video Uretici
setlocal enabledelayedexpansion

set PYTORCH_CUDA_ALLOC_CONF=expandable_segments:True

set PYTHON="D:\__sistem__\Masaustu\FikoYT.Yeni.Cag\video-uretim\LTX-Desktop-WanGP\LTX-Desktop-WanGP\backend\.venv\Scripts\python.exe"
set SCRIPT="D:\__sistem__\Masaustu\FikoYT.Yeni.Cag\video-uretim\ai_influencer_uret.py"

set CHAR=
set TXTFILE=
set URUNS=
set AUDIO=

echo ============================================
echo   AI INFLUENCER VIDEO URETICI
echo   LTX Desktop - Prompt TTS + Lip-Sync
echo ============================================
echo.

REM Surukle birak ile gelen dosyalari ayikla
REM .txt = konusma metni
REM .png/.jpg = ilk resim karakter, sonrakiler urun
for %%A in (%*) do (
    set "EXT=%%~xA"
    if /i "!EXT!"==".txt" set "TXTFILE=%%~A"
    if /i "!EXT!"==".mp3"  set "AUDIO=%%~A"
    if /i "!EXT!"==".wav"  set "AUDIO=%%~A"
    if /i "!EXT!"==".m4a"  set "AUDIO=%%~A"
    if /i "!EXT!"==".flac" set "AUDIO=%%~A"
    if /i "!EXT!"==".ogg"  set "AUDIO=%%~A"
    if /i "!EXT!"==".png"  call :ADDIMG "%%~A"
    if /i "!EXT!"==".jpg"  call :ADDIMG "%%~A"
    if /i "!EXT!"==".jpeg" call :ADDIMG "%%~A"
    if /i "!EXT!"==".webp" call :ADDIMG "%%~A"
    if /i "!EXT!"==".bmp"  call :ADDIMG "%%~A"
)

goto AFTER_DRAG

:ADDIMG
if "%CHAR%"=="" (
    set "CHAR=%~1"
) else (
    set URUNS=!URUNS! "%~1"
)
goto :EOF

:AFTER_DRAG

if "%CHAR%"=="" (
    echo   [!] Karakter resmi gerekli.
    set /p CHAR="  Karakter resmi yolu: "
)
if "%CHAR%"=="" (
    echo HATA: Karakter resmi gerekli!
    pause
    exit /b 1
)

REM Urun yoksa interaktif sor
if not "%URUNS%"=="" goto URUNDONE
echo.
echo   Urun resmi sayisi 0=yok, max 10:
set /p URUNN="  Kac urun tanitilacak Enter=0: "
if "%URUNN%"=="" set URUNN=0
set _U=0
:ASKURUN
if %_U% GEQ %URUNN% goto URUNDONE
set /a _U+=1
set UPATH=
set /p UPATH="  Urun %_U% resmi yolu: "
if not "%UPATH%"=="" set URUNS=%URUNS% "%UPATH%"
goto ASKURUN
:URUNDONE

set METIN_ARG=
if not "%TXTFILE%"=="" goto METINOK
echo.
echo   Konusma metni:
echo     1^) Bir .txt dosyasi sec
echo     2^) Elle yaz
set /p METINSEC="  Seciminiz (1/2, Enter=2): "
if "%METINSEC%"=="1" goto METINFILE
echo.
echo   Metni asagiya yazin sonunda Enter:
set METINTXT=
set /p METINTXT="  > "
set "TXTFILE=%TEMP%\ai_influencer_metin.txt"
>"%TXTFILE%" echo %METINTXT%
goto METINOK
:METINFILE
set /p TXTFILE="  .txt dosya yolu: "
:METINOK
set METIN_ARG=--metin "%TXTFILE%"
echo   Metin dosyasi: %TXTFILE%

echo.
echo   Cozunurluk:
echo     1^) 540p
echo     2^) 720p
echo     3^) 512p
set /p RSEC="  Secim (1-3, Enter=1): "
if "%RSEC%"=="" set RSEC=1
if "%RSEC%"=="1" set RES=540p
if "%RSEC%"=="2" set RES=720p
if "%RSEC%"=="3" set RES=512p

echo.
echo   En-boy:
echo     1^) 16:9 Yatay
echo     2^) 9:16 Dikey
set /p ASEC="  Secim (1-2, Enter=1): "
if "%ASEC%"=="" set ASEC=1
if "%ASEC%"=="1" set ASP=16:9
if "%ASEC%"=="2" set ASP=9:16

echo.
echo   Segment suresi:
echo     1^) 10s
echo     2^) 8s
echo     3^) 6s
echo     4^) 5s
echo     5^) 20s
set /p SSEC="  Secim (1-5, Enter=1): "
if "%SSEC%"=="" set SSEC=1
if "%SSEC%"=="1" set SEG=10
if "%SSEC%"=="2" set SEG=8
if "%SSEC%"=="3" set SEG=6
if "%SSEC%"=="4" set SEG=5
if "%SSEC%"=="5" set SEG=20

echo.
echo   Steps:
echo     1^) 20  hizli
echo     2^) 30  dengeli
echo     3^) 40  yuksek kalite
set /p STSEC="  Secim (1-3, Enter=2): "
if "%STSEC%"=="" set STSEC=2
if "%STSEC%"=="1" set STEPS=20
if "%STSEC%"=="2" set STEPS=30
if "%STSEC%"=="3" set STEPS=40

echo.
echo   Guidance Scale:
echo     1^) 3.5
echo     2^) 4.5
echo     3^) 6.0
set /p GSSEC="  Secim (1-3, Enter=1): "
if "%GSSEC%"=="" set GSSEC=1
if "%GSSEC%"=="1" set GUIDE=3.5
if "%GSSEC%"=="2" set GUIDE=4.5
if "%GSSEC%"=="3" set GUIDE=6.0

echo.
echo   Face Swap:
echo     1^) Kapali
echo     2^) Acik
set /p FSEC="  Secim (1-2, Enter=1): "
set FACE_ARG=
if "%FSEC%"=="2" (
    set /p FACEIMG="  Yuz resmi yolu: "
    if not "!FACEIMG!"=="" set FACE_ARG=--face-swap "!FACEIMG!"
)

echo.
echo ============================================
echo   AYARLAR
echo ============================================
echo   Karakter  : %CHAR%
if not "%AUDIO%"=="" echo   Ses       : %AUDIO%  (model=pro, lip-sync)
if "%AUDIO%"==""    echo   Ses       : YOK (model=fast, prompt-TTS)
if not "%URUNS%"=="" echo   Urunler   :%URUNS%
if "%URUNS%"==""    echo   Urunler   : (yok)
echo   Cozunurluk: %RES%   Oran: %ASP%   Segment: %SEG%s
echo   Steps     : %STEPS%   Guidance: %GUIDE%
if not "%FACE_ARG%"=="" echo   FaceSwap  : ACIK
echo ============================================
echo.
echo   NOT: LTX Desktop acik olmali!
echo   Enter = baslat, Ctrl+C = iptal
pause >nul

set SES_ARG=
if not "%AUDIO%"=="" set SES_ARG=--ses "%AUDIO%"

%PYTHON% %SCRIPT% %METIN_ARG% --karakter "%CHAR%" --urun %URUNS% --resolution %RES% --aspect %ASP% --segment-duration %SEG% --steps %STEPS% --guidance-scale %GUIDE% %FACE_ARG% %SES_ARG%

echo.
echo ============================================
echo   Islem tamamlandi!
echo ============================================
pause